projects/guix·blob java-team · refs

80 lines · 3.4 KiB

1;;; GNU Guix --- Functional package management for GNU
2;;; Copyright © 2019 Danny Milosavljevic <[email protected]>
3;;; Copyright © 2020 Robin Green <[email protected]>
4;;;
5;;; This file is part of GNU Guix.
6;;;
7;;; GNU Guix is free software; you can redistribute it and/or modify it
8;;; under the terms of the GNU General Public License as published by
9;;; the Free Software Foundation; either version 3 of the License, or (at
10;;; your option) any later version.
11;;;
12;;; GNU Guix is distributed in the hope that it will be useful, but
13;;; WITHOUT ANY WARRANTY; without even the implied warranty of
14;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15;;; GNU General Public License for more details.
16;;;
17;;; You should have received a copy of the GNU General Public License
18;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
19
20(define-module (gnu services auditd)
21 #:use-module (gnu services)
22 #:use-module (gnu services configuration)
23 #:use-module (gnu services base)
24 #:use-module (gnu services shepherd)
25 #:use-module (gnu packages admin)
26 #:use-module (guix records)
27 #:use-module (guix gexp)
28 #:use-module (guix packages)
29 #:export (auditd-configuration
30 auditd-service-type
31 %default-auditd-configuration-directory))
32
33(define auditd.conf
34 (plain-file "auditd.conf" "log_file = /var/log/audit/audit.log\nlog_format = \
35ENRICHED\nfreq = 1\nspace_left = 5%\nspace_left_action = \
36syslog\nadmin_space_left_action = ignore\ndisk_full_action = \
37ignore\ndisk_error_action = syslog\n"))
38
39(define %default-auditd-configuration-directory
40 (computed-file "auditd"
41 #~(begin
42 (mkdir #$output)
43 (copy-file #$auditd.conf
44 (string-append #$output "/auditd.conf")))))
45
46(define-record-type* <auditd-configuration>
47 auditd-configuration make-auditd-configuration
48 auditd-configuration?
49 (audit auditd-configuration-audit ; file-like
50 (default audit))
51 (configuration-directory auditd-configuration-configuration-directory)) ; file-like
52
53(define %auditd-activation
54 #~(begin
55 (mkdir-p "/var/log/audit")))
56
57(define (auditd-shepherd-service config)
58 (let* ((audit (auditd-configuration-audit config))
59 (configuration-directory (auditd-configuration-configuration-directory config)))
60 (list (shepherd-service
61 (documentation "Auditd allows you to audit file system accesses and process execution.")
62 (provision '(auditd))
63 (requirement '(user-processes))
64 (start #~(make-forkexec-constructor
65 (list (string-append #$audit "/sbin/auditd") "-c" #$configuration-directory)
66 #:pid-file "/var/run/auditd.pid"))
67 (stop #~(make-kill-destructor))))))
68
69(define auditd-service-type
70 (service-type (name 'auditd)
71 (description "Allows auditing file system accesses and process execution.")
72 (extensions
73 (list
74 (service-extension shepherd-root-service-type
75 auditd-shepherd-service)
76 (service-extension activation-service-type
77 (const %auditd-activation))))
78 (default-value
79 (auditd-configuration
80 (configuration-directory %default-auditd-configuration-directory)))))