projects/guix·blob javascript-team · refs

662 lines · 28.0 KiB

1;;; GNU Guix --- Functional package management for GNU
2;;; Copyright © 2012 Nikita Karetnikov <[email protected]>
3;;; Copyright © 2012-2018, 2020-2022 Ludovic Courtès <[email protected]>
4;;; Copyright © 2015 Mathieu Lirzin <[email protected]>
5;;; Copyright © 2014 Manolis Fragkiskos Ragkousis <[email protected]>
6;;; Copyright © 2015, 2017, 2018 Mark H Weaver <[email protected]>
7;;; Copyright © 2016 David Thompson <[email protected]>
8;;; Copyright © 2017 Nikita <[email protected]>
9;;; Copyright © 2017, 2019, 2021, 2022 Efraim Flashner <[email protected]>
10;;; Copyright © 2018 Tobias Geerinckx-Rice <[email protected]>
11;;; Copyright © 2018 Ricardo Wurmus <[email protected]>
12;;; Copyright © 2019 Pierre-Moana Levesque <[email protected]>
13;;; Copyright © 2020, 2023, 2024, 2025 Janneke Nieuwenhuizen <[email protected]>
14;;; Copyright © 2021 Maxim Cournoyer <[email protected]>
15;;; Copyright © 2022 Marius Bakke <[email protected]>
16;;; Copyright © 2025 John Kehayias <[email protected]>
17;;;
18;;; This file is part of GNU Guix.
19;;;
20;;; GNU Guix is free software; you can redistribute it and/or modify it
21;;; under the terms of the GNU General Public License as published by
22;;; the Free Software Foundation; either version 3 of the License, or (at
23;;; your option) any later version.
24;;;
25;;; GNU Guix is distributed in the hope that it will be useful, but
26;;; WITHOUT ANY WARRANTY; without even the implied warranty of
27;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
28;;; GNU General Public License for more details.
29;;;
30;;; You should have received a copy of the GNU General Public License
31;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
32
33(define-module (gnu packages autotools)
34 #:use-module (guix licenses)
35 #:use-module (gnu packages)
36 #:use-module (gnu packages gcc)
37 #:use-module (gnu packages perl)
38 #:use-module (gnu packages python)
39 #:use-module (gnu packages m4)
40 #:use-module (gnu packages man)
41 #:use-module (gnu packages bash)
42 #:use-module (guix utils)
43 #:use-module (guix packages)
44 #:use-module (guix download)
45 #:use-module (guix git-download)
46 #:use-module (guix gexp)
47 #:use-module (guix build-system gnu)
48 #:use-module (guix build-system trivial)
49 #:use-module (ice-9 match)
50 #:export (autoconf-wrapper))
51
52(define-public autoconf-2.69
53 (package
54 (name "autoconf")
55 (version "2.69")
56 (source
57 (origin
58 (method url-fetch)
59 (uri (string-append "mirror://gnu/autoconf/autoconf-"
60 version ".tar.xz"))
61 (sha256
62 (base32
63 "113nlmidxy9kjr45kg9x3ngar4951mvag1js2a3j8nxcz34wxsv4"))))
64 (build-system gnu-build-system)
65 (inputs
66 (list bash-minimal m4 perl))
67 (native-inputs
68 (list perl m4))
69 (arguments
70 (list
71 ;; XXX: testsuite: 209 and 279 failed. The latter is an impurity. It
72 ;; should use our own "cpp" instead of "/lib/cpp".
73 #:tests? #f
74 #:phases
75 #~(modify-phases %standard-phases
76 #$@(if (%current-target-system)
77 #~((add-after 'install 'patch-non-shebang-references
78 (lambda* (#:key build inputs #:allow-other-keys)
79 ;; `patch-shebangs' patches shebangs only, and the Perl
80 ;; scripts use a re-exec feature that references the
81 ;; build hosts' perl. Also, BASH and M4 store references
82 ;; hide in the scripts.
83 (let ((bash (dirname (dirname
84 (search-input-file inputs "bin/bash"))))
85 (m4 (dirname (dirname
86 (search-input-file inputs "bin/m4"))))
87 (perl (dirname (dirname
88 (search-input-file inputs "bin/perl"))))
89 (store-directory (%store-directory)))
90 (substitute* (find-files (string-append #$output "/bin"))
91 (((string-append store-directory "/[^/]*-bash-[^/]*"))
92 bash)
93 (((string-append store-directory "/[^/]*-m4-[^/]*"))
94 m4)
95 (((string-append store-directory "/[^/]*-perl-[^/]*"))
96 perl))))))
97 '())
98 (add-after 'install 'unpatch-shebangs
99 (lambda _
100 ;; Scripts that "autoconf -i" installs (config.guess,
101 ;; config.sub, and install-sh) must use a regular shebang
102 ;; rather than a reference to the store. Restore it.
103 (let ((build-aux (string-append #$output
104 "/share/autoconf/build-aux")))
105 (substitute* (find-files build-aux)
106 (("^#!.*/bin/sh") "#!/bin/sh"))))))))
107 (home-page "https://www.gnu.org/software/autoconf/")
108 (synopsis "Create source code configuration scripts")
109 (description
110 "Autoconf offers the developer a robust set of M4 macros which expand
111into shell code to test the features of Unix-like systems and to adapt
112automatically their software package to these systems. The resulting shell
113scripts are self-contained and portable, freeing the user from needing to
114know anything about Autoconf or M4.")
115 (license gpl3+))) ; some files are under GPLv2+
116
117;; This is the renaissance version, which is not widely supported yet.
118(define-public autoconf-2.71
119 (package
120 (inherit autoconf-2.69)
121 (version "2.71")
122 (source
123 (origin
124 (method url-fetch)
125 (uri (string-append "mirror://gnu/autoconf/autoconf-"
126 version ".tar.xz"))
127 (sha256
128 (base32
129 "197sl23irn6s9pd54rxj5vcp5y8dv65jb9yfqgr2g56cxg7q6k7i"))))
130 (arguments
131 (substitute-keyword-arguments (package-arguments autoconf-2.69)
132 ((#:tests? _ #f)
133 ;; FIXME: To run the test suite, fix all the instances where scripts
134 ;; generates "#! /bin/sh" shebangs.
135 #f)
136 ((#:phases phases #~%standard-phases)
137 #~(modify-phases #$phases
138 (add-before 'check 'prepare-tests
139 (lambda _
140 (for-each patch-shebang
141 (append (find-files "tests"
142 (lambda (file stat)
143 (executable-file? file)))
144 (find-files "bin"
145 (lambda (file stat)
146 (executable-file? file)))))))))))))
147
148(define-public autoconf-2.72
149 (package (inherit autoconf-2.71)
150 (version "2.72")
151 (source
152 (origin
153 (method url-fetch)
154 (uri (string-append "mirror://gnu/autoconf/autoconf-"
155 version ".tar.xz"))
156 (sha256
157 (base32
158 "0niz4852fgyavfh3gr4h4kzalk01nk70v6vfsja6r3ap349mr25s"))))))
159
160(define-public autoconf autoconf-2.69)
161
162(define-public autoconf-2.68
163 (package (inherit autoconf)
164 (version "2.68")
165 (source
166 (origin
167 (method url-fetch)
168 (uri (string-append "mirror://gnu/autoconf/autoconf-"
169 version ".tar.xz"))
170 (sha256
171 (base32
172 "1fjm21k2na07f3vasf288a0zx66lbv0hd3l9bvv3q8p62s3pg569"))))))
173
174(define-public autoconf-2.64
175 (package (inherit autoconf)
176 (version "2.64")
177 (source
178 (origin
179 (method url-fetch)
180 (uri (string-append "mirror://gnu/autoconf/autoconf-"
181 version ".tar.xz"))
182 (sha256
183 (base32
184 "0j3jdjpf5ly39dlp0bg70h72nzqr059k0x8iqxvaxf106chpgn9j"))))))
185
186(define-public autoconf-2.13
187 ;; GNU IceCat 52.x requires autoconf-2.13 to build!
188 (package (inherit autoconf)
189 (version "2.13")
190 (source
191 (origin
192 (method url-fetch)
193 (uri (string-append "mirror://gnu/autoconf/autoconf-"
194 version ".tar.gz"))
195 (sha256
196 (base32
197 "07krzl4czczdsgzrrw9fiqx35xcf32naf751khg821g5pqv12qgh"))))
198 (arguments
199 `(#:tests? #f
200 #:phases
201 ;; The 'configure' script in autoconf-2.13 can't cope with "SHELL=" and
202 ;; "CONFIG_SHELL=" arguments, so we set them as environment variables
203 ;; and pass a simplified set of arguments.
204 (modify-phases %standard-phases
205 (replace 'configure
206 (lambda* (#:key build inputs outputs #:allow-other-keys)
207 (let ((bash (which "bash"))
208 (out (assoc-ref outputs "out")))
209 (setenv "CONFIG_SHELL" bash)
210 (setenv "SHELL" bash)
211 (invoke bash "./configure"
212 (string-append "--prefix=" out)
213 (string-append "--build=" build))))))))))
214
215
216(define (make-autoconf-wrapper autoconf)
217 "Return a wrapper around AUTOCONF that generates `configure' scripts that
218use our own Bash instead of /bin/sh in shebangs. For that reason, it should
219only be used internally---users should not end up distributing `configure'
220files with a system-specific shebang."
221 (package
222 (inherit autoconf)
223 (name (string-append (package-name autoconf) "-wrapper"))
224 (build-system trivial-build-system)
225 (inputs
226 (list
227 ;; XXX: Kludge to hide the circular dependency.
228 (module-ref (resolve-interface '(gnu packages guile))
229 'guile-3.0/pinned)
230 autoconf
231 bash-minimal))
232 (arguments
233 (list
234 #:modules '((guix build utils))
235 #:builder
236 #~(begin
237 (use-modules (guix build utils))
238 (let ((bin (string-append #$output "/bin"))
239 (autoconf (search-input-file %build-inputs "/bin/autoconf"))
240 (guile (search-input-file %build-inputs "/bin/guile"))
241 (sh (search-input-file %build-inputs "/bin/sh"))
242 (modules ((compose dirname dirname dirname)
243 (search-path %load-path
244 "guix/build/utils.scm"))))
245 (mkdir-p bin)
246
247 ;; Symlink all the binaries but `autoconf'.
248 (with-directory-excursion bin
249 (for-each (lambda (file)
250 (unless (string=? (basename file) "autoconf")
251 (symlink file (basename file))))
252 (find-files (dirname autoconf) ".*")))
253
254 ;; Add an `autoconf' binary that wraps the real one.
255 (call-with-output-file (string-append bin "/autoconf")
256 (lambda (port)
257 ;; Shamefully, Guile can be used in shebangs only if a
258 ;; single argument is passed (-ds); otherwise it gets
259 ;; them all as a single argument and fails to parse them.
260 (format port "#!~a
261export GUILE_LOAD_PATH=\"~a\"
262export GUILE_LOAD_COMPILED_PATH=\"~a\"
263exec ~a --no-auto-compile \"$0\" \"$@\"
264!#~%"
265 sh modules modules guile)
266 (write
267 `(begin
268 (use-modules (guix build utils))
269 (let ((result (apply system* ,autoconf
270 (cdr (command-line)))))
271 (when (and (file-exists? "configure")
272 (not (file-exists? "/bin/sh")))
273 ;; Patch regardless of RESULT, because `autoconf
274 ;; -Werror' can both create a `configure' file and
275 ;; return a non-zero exit code.
276 (patch-shebang "configure"))
277 (exit (status:exit-val result))))
278 port)))
279 (chmod (string-append bin "/autoconf") #o555)))))
280
281 ;; Do not show it in the UI since it's meant for internal use.
282 (properties '((hidden? . #t)))))
283
284;; Only use this package when autoconf is not usable,
285;; see <https://issues.guix.gnu.org/46564#1>.
286(define-public autoconf-wrapper
287 (make-autoconf-wrapper autoconf))
288
289(define-public autoconf-archive
290 (package
291 (name "autoconf-archive")
292 (version "2023.02.20")
293 (source
294 (origin
295 (method url-fetch)
296 (uri (string-append "mirror://gnu/autoconf-archive/autoconf-archive-"
297 version ".tar.xz"))
298 (sha256
299 (base32
300 "0cqsqdnmjdyybzw8wqhwkgs1vh7r5pbw66a6g7sz2a5fg6209m3i"))))
301 (build-system gnu-build-system)
302 (home-page "https://www.gnu.org/software/autoconf-archive/")
303 (synopsis "Collection of freely reusable Autoconf macros")
304 (description
305 "Autoconf Archive is a collection of over 450 new macros for Autoconf,
306greatly expanding the domain of its functionality. These macros have been
307contributed as free software by the community.")
308 (license gpl3+)))
309
310(define-public autobuild
311 (package
312 (name "autobuild")
313 (version "5.3")
314 (source (origin
315 (method url-fetch)
316 (uri (string-append "mirror://savannah/autobuild/autobuild-"
317 version ".tar.gz"))
318 (sha256
319 (base32
320 "0gv7g61ja9q9zg1m30k4snqwwy1kq7b4df6sb7d2qra7kbdq8af1"))))
321 (build-system gnu-build-system)
322 (inputs (list perl))
323 (synopsis "Process generated build logs")
324 (description "Autobuild is a package that processes build logs generated
325when building software. Autobuild is primarily focused on packages using
326Autoconf and Automake, but can be used with other build systems too.
327Autobuild generates an HTML summary file, containing links to each build log.
328The summary includes project name, version, build hostname, host type (cross
329compile aware), date of build, and indication of success or failure. The
330output is indexed in many ways to simplify browsing.")
331 (home-page "https://josefsson.org/autobuild/")
332 (license gpl3+)))
333
334(define-public automake-1.16.5
335 (package
336 (name "automake")
337 (version "1.16.5")
338 (source (origin
339 (method url-fetch)
340 (uri (string-append "mirror://gnu/automake/automake-"
341 version ".tar.xz"))
342 (sha256
343 (base32
344 "0sdl32qxdy7m06iggmkkvf7j520rmmgbsjzbm7fgnxwxdp6mh7gh"))
345 (patches
346 (search-patches "automake-skip-amhello-tests.patch"))))
347 (build-system gnu-build-system)
348 (inputs
349 (list autoconf-wrapper bash-minimal perl))
350 (native-inputs
351 (list autoconf-wrapper perl))
352 (native-search-paths
353 (list (search-path-specification
354 (variable "ACLOCAL_PATH")
355 (files '("share/aclocal")))))
356 (arguments
357 (list
358 #:tests? #f ;with gcc-14, 23 compiler "tap" tests fail.
359 #:modules '((guix build gnu-build-system)
360 (guix build utils)
361 (srfi srfi-1)
362 (srfi srfi-26)
363 (rnrs io ports))
364 #:phases
365 #~(modify-phases %standard-phases
366 (add-before 'patch-source-shebangs 'patch-tests-shebangs
367 (lambda* (#:key native-inputs inputs #:allow-other-keys)
368 (let ((sh (search-input-file (or native-inputs inputs) "bin/sh")))
369 (substitute* (find-files "t" "\\.(sh|tap)$")
370 (("#![[:blank:]]?/bin/sh")
371 (string-append "#!" sh)))
372
373 ;; Set these variables for all the `configure' runs
374 ;; that occur during the test suite.
375 (setenv "SHELL" sh)
376 (setenv "CONFIG_SHELL" sh))))
377
378 #$@(if (%current-target-system)
379 #~((add-after 'install 'patch-non-shebang-references
380 (lambda* (#:key inputs #:allow-other-keys)
381 ;; `patch-shebangs' patches shebangs only, and the Perl
382 ;; scripts use a re-exec feature that references the
383 ;; build hosts' perl. Also, AUTOCONF and BASH store
384 ;; references hide in the scripts.
385 (let ((autoconf
386 (dirname (dirname
387 (search-input-file inputs "bin/autoconf"))))
388 (bash
389 (dirname (dirname
390 (search-input-file inputs "bin/bash"))))
391 (perl
392 (dirname (dirname
393 (search-input-file inputs "bin/perl"))))
394 (store-directory (%store-directory)))
395 (substitute* (find-files (string-append #$output "/bin"))
396 (((string-append store-directory "/[^/]*-autoconf-[^/]*"))
397 autoconf)
398 (((string-append store-directory "/[^/]*-bash-[^/]*"))
399 bash)
400 (((string-append store-directory "/[^/]*-perl-[^/]*"))
401 perl))))))
402 '())
403
404 ;; Files like `install-sh', `mdate.sh', etc. must use
405 ;; #!/bin/sh, otherwise users could leak erroneous shebangs
406 ;; in the wild. See <http://bugs.gnu.org/14201> for an
407 ;; example.
408 (add-after 'install 'unpatch-shebangs
409 (lambda _
410 (let ((dir (string-append #$output "/share")))
411 (define (starts-with-shebang? file)
412 (equal? (call-with-input-file file
413 (lambda (p)
414 (list (get-u8 p) (get-u8 p))))
415 (map char->integer '(#\# #\!))))
416
417 (for-each (lambda (file)
418 (when (and (starts-with-shebang? file)
419 (executable-file? file))
420 (format #t "restoring shebang on `~a'~%"
421 file)
422 (substitute* file
423 (("^#!.*/bin/sh")
424 "#!/bin/sh")
425 (("^#!.*/bin/env(.*)$" _ args)
426 (string-append "#!/usr/bin/env"
427 args)))))
428 (find-files dir ".*"))))))))
429 (home-page "https://www.gnu.org/software/automake/")
430 (synopsis "Making GNU standards-compliant Makefiles")
431 (description
432 "Automake the part of the GNU build system for producing
433standards-compliant Makefiles. Build requirements are entered in an
434intuitive format and then Automake works with Autoconf to produce a robust
435Makefile, simplifying the entire process for the developer.")
436 (license gpl2+))) ; some files are under GPLv3+
437
438(define-public automake
439 (package/inherit automake-1.16.5
440 (name "automake")
441 (version "1.17")
442 (source (origin
443 (method url-fetch)
444 (uri (string-append "mirror://gnu/automake/automake-"
445 version ".tar.xz"))
446 (sha256
447 (base32
448 "146rkdcwri2dkwn3pjrjs9v0wm4xyav9vvq4yw5vj4qy87yc2849"))
449 (patches
450 (search-patches "automake-skip-amhello-tests.patch"))))
451 (arguments
452 (substitute-keyword-arguments (package-arguments automake-1.16.5)
453 ((#:tests? tests?)
454 #t)
455 ((#:phases phases)
456 #~(modify-phases #$phases
457 (add-before 'check 'skip-test
458 (lambda _
459 (substitute*
460 ;; This test requires 'etags' and fails if it's missing.
461 '("t/tags-lisp-space.sh"
462 ;; This test fails, probably a timestamp thing:
463 ;; make: Nothing to be done for 'all'.
464 "t/remake-aclocal-version-mismatch.sh"
465 ;; Non-deterministic test failures:
466 "t/aclocal-autoconf-version-check.sh"
467 "t/backcompat2.sh"
468 "t/backcompat3.sh"
469 "t/nodef.sh"
470 "t/nodef2.sh")
471 (("^#!.*" all)
472 (string-append all "exit 77;\n")))))
473 #$@(if (%current-target-system)
474 #~((add-before 'check 'cross-skip-tests
475 (lambda _
476 ;; These tests try to execute a cross-built program
477 (substitute* '("t/dist-vs-built-sources.sh"
478 "t/subobj-objname-clash.sh")
479 (("^#!.*" all)
480 (string-append all "exit 77;\n"))))))
481 #~())))))))
482
483(define-public libtool
484 (package
485 (name "libtool")
486 (version "2.4.7")
487 (source (origin
488 (method url-fetch)
489 (uri (string-append "mirror://gnu/libtool/libtool-"
490 version ".tar.xz"))
491 (sha256
492 (base32
493 "0pb3l4x37k6fj1lwnpzws55gi3pxl0hx56jm4bzmbrkw0mzj2zsg"))
494 (patches (search-patches "libtool-skip-tests2.patch"
495 "libtool-grep-compat.patch"))))
496 (build-system gnu-build-system)
497 (propagated-inputs (list m4))
498 (native-inputs
499 (list m4
500 perl
501 ;; XXX: this shouldn't be necessary, but without it test
502 ;; 102 fails because it cannot find ltdl/libltdl.la.
503 libltdl
504 help2man ; because we modify ltmain.sh
505 automake ; some tests rely on 'aclocal'
506 autoconf-wrapper)) ; others on 'autom4te'
507
508 (arguments
509 `(;; Libltdl is provided as a separate package, so don't install it here.
510 #:configure-flags '("--disable-ltdl-install")
511
512 ;; XXX: There are test failures on mips64el-linux starting from 2.4.4:
513 ;; <http://hydra.gnu.org/build/181662>.
514 ;; Also, do not run tests when cross compiling
515 #:tests? ,(not (or (%current-target-system)
516 (string-prefix? "mips64"
517 (%current-system))))
518
519 #:phases
520 (modify-phases %standard-phases
521 (add-before 'check 'pre-check
522 (lambda* (#:key inputs native-inputs parallel-tests? #:allow-other-keys)
523 ;; Run the test suite in parallel, if possible.
524 (setenv "TESTSUITEFLAGS"
525 (string-append
526 "-j"
527 (if parallel-tests?
528 (number->string (parallel-job-count))
529 "1")))
530 ;; Patch references to /bin/sh.
531 (let ((/bin/sh (search-input-file (or native-inputs inputs) "bin/sh")))
532 (substitute* "tests/testsuite"
533 (("/bin/sh") /bin/sh)))))
534 ;; These files may be copied into source trees by libtoolize,
535 ;; therefore they must not point to store file names that would be
536 ;; leaked with tarballs generated by make dist.
537 (add-after 'install 'restore-build-aux-shebang
538 (lambda* (#:key outputs #:allow-other-keys)
539 (let* ((out (assoc-ref outputs "out"))
540 (dir (string-append out "/share/libtool/build-aux")))
541 (for-each (lambda (file)
542 (format #t "restoring shebang on `~a'~%" file)
543 (substitute* file
544 (("^#!.*/bin/sh") "#!/bin/sh")))
545 (find-files dir))))))))
546
547 (synopsis "Generic shared library support tools")
548 (description
549 "GNU Libtool helps in the creation and use of shared libraries, by
550presenting a single consistent, portable interface that hides the usual
551complexity of working with shared libraries across platforms.")
552 (license gpl3+)
553 (home-page "https://www.gnu.org/software/libtool/")))
554
555(define-public config
556 (let ((revision "1")
557 (commit "c8ddc8472f8efcadafc1ef53ca1d863415fddd5f"))
558 (package
559 (name "config")
560 (version (git-version "0.0.0" revision commit)) ;no release tag
561 (source (origin
562 (method git-fetch)
563 (uri (git-reference
564 (url "https://git.savannah.gnu.org/git/config.git/")
565 (commit commit)))
566 (file-name (git-file-name name version))
567 (sha256
568 (base32
569 "0x6ycvkmmhhhag97wsf0pw8n5fvh12rjvrck90rz17my4ys16qwv"))))
570 (build-system gnu-build-system)
571 (arguments
572 `(#:phases (modify-phases %standard-phases
573 (add-after 'unpack 'patch-/bin/sh
574 (lambda _
575 (substitute* "testsuite/config-guess.sh"
576 (("#!/bin/sh")
577 (string-append "#!" (which "sh"))))
578 #t))
579 (replace 'build
580 (lambda _
581 (invoke "make" "manpages")))
582 (delete 'configure)
583 (replace 'install
584 (lambda* (#:key outputs #:allow-other-keys)
585 (let* ((out (assoc-ref outputs "out"))
586 (bin (string-append out "/bin"))
587 (man1 (string-append out "/share/man/man1")))
588 (install-file "config.guess" bin)
589 (install-file "config.sub" bin)
590 (install-file "doc/config.guess.1" man1)
591 (install-file "doc/config.sub.1" man1)
592 #t))))))
593 (native-inputs
594 (list help2man))
595 (home-page "https://savannah.gnu.org/projects/config")
596 (synopsis "Ubiquitous config.guess and config.sub scripts")
597 (description "The `config.guess' script tries to guess a canonical system triple,
598and `config.sub' validates and canonicalizes. These are used as part of
599configuration in nearly all GNU packages (and many others).")
600 (license gpl2+))))
601
602(define-public libltdl
603 ;; This is a libltdl package separate from the libtool package. This is
604 ;; useful because, unlike libtool, it has zero extra dependencies (making it
605 ;; readily usable during bootstrap), and it builds very quickly since
606 ;; Libtool's extensive test suite isn't run.
607 (package
608 (name "libltdl")
609 (version "2.4.7")
610 (source (origin
611 (method url-fetch)
612 (uri (string-append "mirror://gnu/libtool/libtool-"
613 version ".tar.xz"))
614 (sha256
615 (base32
616 "0pb3l4x37k6fj1lwnpzws55gi3pxl0hx56jm4bzmbrkw0mzj2zsg"))))
617 (build-system gnu-build-system)
618 (arguments
619 '(#:configure-flags '("--enable-ltdl-install") ;really install it
620 #:phases (modify-phases %standard-phases
621 (add-before 'configure 'change-directory
622 (lambda _ (chdir "libltdl"))))))
623
624 (synopsis "System-independent dlopen wrapper of GNU libtool")
625 (description (package-description libtool))
626 (home-page (package-home-page libtool))
627 (license lgpl2.1+)))
628
629(define-public pyconfigure
630 (package
631 (name "pyconfigure")
632 (version "0.2.3")
633 (source (origin
634 (method url-fetch)
635 (uri (string-append "mirror://gnu/pyconfigure/pyconfigure-"
636 version ".tar.gz"))
637 (sha256
638 (base32
639 "0kxi9bg7l6ric39vbz9ykz4a21xlihhh2zcc3297db8amvhqwhrp"))))
640 (build-system gnu-build-system)
641 (arguments
642 `(#:phases
643 (modify-phases %standard-phases
644 (add-before 'configure 'patch-python
645 (lambda _
646 (substitute* "pyconf.in"
647 (("/usr/bin/env python") (which "python3")))
648 #t)))))
649 (inputs
650 (list python-3))
651 (synopsis "@command{configure} interface for Python-based packages")
652 (description
653 "GNU pyconfigure provides template files for easily implementing
654standards-compliant configure scripts and Makefiles for Python-based packages.
655It is designed to work alongside existing Python setup scripts, making it easy
656to integrate into existing projects. Powerful and flexible Autoconf macros
657are available, allowing you to easily make adjustments to the installation
658procedure based on the capabilities of the target computer.")
659 (home-page "https://www.gnu.org/software/pyconfigure/manual/")
660 (license
661 (fsf-free
662 "https://www.gnu.org/prep/maintain/html_node/License-Notices-for-Other-Files.html"))))