projects/guix·blob version-1.2.0 · refs

533 lines · 22.1 KiB

1;;; GNU Guix --- Functional package management for GNU
2;;; Copyright © 2019 Jakob L. Kreuze <[email protected]>
3;;; Copyright © 2020 Ludovic Courtès <[email protected]>
4;;;
5;;; This file is part of GNU Guix.
6;;;
7;;; GNU Guix is free software; you can redistribute it and/or modify it
8;;; under the terms of the GNU General Public License as published by
9;;; the Free Software Foundation; either version 3 of the License, or (at
10;;; your option) any later version.
11;;;
12;;; GNU Guix is distributed in the hope that it will be useful, but
13;;; WITHOUT ANY WARRANTY; without even the implied warranty of
14;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15;;; GNU General Public License for more details.
16;;;
17;;; You should have received a copy of the GNU General Public License
18;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
19
20(define-module (gnu machine ssh)
21 #:use-module (gnu bootloader)
22 #:use-module (gnu machine)
23 #:autoload (gnu packages gnupg) (guile-gcrypt)
24 #:use-module (gnu system)
25 #:use-module (gnu system file-systems)
26 #:use-module (gnu system uuid)
27 #:use-module ((gnu services) #:select (sexp->system-provenance))
28 #:use-module (guix diagnostics)
29 #:use-module (guix gexp)
30 #:use-module (guix i18n)
31 #:use-module (guix modules)
32 #:use-module (guix monads)
33 #:use-module (guix pki)
34 #:use-module (guix records)
35 #:use-module (guix remote)
36 #:use-module (guix scripts system reconfigure)
37 #:use-module (guix ssh)
38 #:use-module (guix store)
39 #:use-module (guix utils)
40 #:use-module ((guix self) #:select (make-config.scm))
41 #:use-module (gcrypt pk-crypto)
42 #:use-module (ice-9 format)
43 #:use-module (ice-9 match)
44 #:use-module (ice-9 textual-ports)
45 #:use-module (srfi srfi-1)
46 #:use-module (srfi srfi-9)
47 #:use-module (srfi srfi-19)
48 #:use-module (srfi srfi-26)
49 #:use-module (srfi srfi-34)
50 #:use-module (srfi srfi-35)
51 #:export (managed-host-environment-type
52
53 machine-ssh-configuration
54 machine-ssh-configuration?
55 machine-ssh-configuration
56
57 machine-ssh-configuration-host-name
58 machine-ssh-configuration-build-locally?
59 machine-ssh-configuration-authorize?
60 machine-ssh-configuration-allow-downgrades?
61 machine-ssh-configuration-port
62 machine-ssh-configuration-user
63 machine-ssh-configuration-host-key
64 machine-ssh-configuration-session))
65
66;;; Commentary:
67;;;
68;;; This module implements remote evaluation and system deployment for
69;;; machines that are accessible over SSH and have a known host-name. In the
70;;; sense of the broader "machine" interface, we describe the environment for
71;;; such machines as 'managed-host.
72;;;
73;;; Code:
74
75
76;;;
77;;; Parameters for the SSH client.
78;;;
79
80(define-record-type* <machine-ssh-configuration> machine-ssh-configuration
81 make-machine-ssh-configuration
82 machine-ssh-configuration?
83 (host-name machine-ssh-configuration-host-name) ; string
84 (system machine-ssh-configuration-system) ; string
85 (build-locally? machine-ssh-configuration-build-locally? ; boolean
86 (default #t))
87 (authorize? machine-ssh-configuration-authorize? ; boolean
88 (default #t))
89 (allow-downgrades? machine-ssh-configuration-allow-downgrades? ; boolean
90 (default #f))
91 (port machine-ssh-configuration-port ; integer
92 (default 22))
93 (user machine-ssh-configuration-user ; string
94 (default "root"))
95 (identity machine-ssh-configuration-identity ; path to a private key
96 (default #f))
97 (session machine-ssh-configuration-session ; session
98 (default #f))
99 (host-key machine-ssh-configuration-host-key ; #f | string
100 (default #f)))
101
102(define (machine-ssh-session machine)
103 "Return the SSH session that was given in MACHINE's configuration, or create
104one from the configuration's parameters if one was not provided."
105 (maybe-raise-unsupported-configuration-error machine)
106 (let ((config (machine-configuration machine)))
107 (or (machine-ssh-configuration-session config)
108 (let ((host-name (machine-ssh-configuration-host-name config))
109 (user (machine-ssh-configuration-user config))
110 (port (machine-ssh-configuration-port config))
111 (identity (machine-ssh-configuration-identity config))
112 (host-key (machine-ssh-configuration-host-key config)))
113 (unless host-key
114 (warning (G_ "<machine-ssh-configuration> without a 'host-key' \
115is deprecated~%")))
116 (open-ssh-session host-name
117 #:user user
118 #:port port
119 #:identity identity
120 #:host-key host-key)))))
121
122
123;;;
124;;; Remote evaluation.
125;;;
126
127(define (machine-become-command machine)
128 "Return as a list of strings the program and arguments necessary to run a
129shell command with escalated privileges for MACHINE's configuration."
130 (if (string= "root" (machine-ssh-configuration-user
131 (machine-configuration machine)))
132 '()
133 '("/run/setuid-programs/sudo" "-n" "--")))
134
135(define (managed-host-remote-eval machine exp)
136 "Internal implementation of 'machine-remote-eval' for MACHINE instances with
137an environment type of 'managed-host."
138 (maybe-raise-unsupported-configuration-error machine)
139 (let ((config (machine-configuration machine)))
140 (remote-eval exp (machine-ssh-session machine)
141 #:build-locally?
142 (machine-ssh-configuration-build-locally? config)
143 #:system
144 (machine-ssh-configuration-system config)
145 #:become-command
146 (machine-become-command machine))))
147
148
149;;;
150;;; Safety checks.
151;;;
152
153;; Assertion to be executed remotely. This abstraction exists to allow us to
154;; gather a list of expressions to be evaluated and eventually evaluate them
155;; all at once instead of one by one. (This is pretty much a monad.)
156(define-record-type <remote-assertion>
157 (remote-assertion exp proc)
158 remote-assertion?
159 (exp remote-assertion-expression)
160 (proc remote-assertion-procedure))
161
162(define-syntax-rule (remote-let ((var exp)) body ...)
163 "Return a <remote-assertion> that binds VAR to the result of evaluating EXP,
164a gexp, remotely, and evaluate BODY in that context."
165 (remote-assertion exp (lambda (var) body ...)))
166
167(define (machine-check-file-system-availability machine)
168 "Return a list of <remote-assertion> that raise a '&message' error condition
169if any of the file-systems specified in MACHINE's 'system' declaration do not
170exist on the machine."
171 (define file-systems
172 (filter (lambda (fs)
173 (and (file-system-mount? fs)
174 (not (member (file-system-type fs)
175 %pseudo-file-system-types))
176 ;; Don't try to validate network file systems.
177 (not (string-prefix? "nfs" (file-system-type fs)))
178 (not (memq 'bind-mount (file-system-flags fs)))))
179 (operating-system-file-systems (machine-operating-system machine))))
180
181 (define (check-literal-file-system fs)
182 (remote-let ((errno #~(catch 'system-error
183 (lambda ()
184 (stat #$(file-system-device fs))
185 #t)
186 (lambda args
187 (system-error-errno args)))))
188 (when (number? errno)
189 (raise (formatted-message (G_ "device '~a' not found: ~a")
190 (file-system-device fs)
191 (strerror errno))))))
192
193 (define (check-labeled-file-system fs)
194 (define remote-exp
195 (with-imported-modules (source-module-closure
196 '((gnu build file-systems)))
197 #~(begin
198 (use-modules (gnu build file-systems))
199 (find-partition-by-label #$(file-system-label->string
200 (file-system-device fs))))))
201
202 (remote-let ((result remote-exp))
203 (unless result
204 (raise (formatted-message (G_ "no file system with label '~a'")
205 (file-system-label->string
206 (file-system-device fs)))))))
207
208 (define (check-uuid-file-system fs)
209 (define remote-exp
210 (with-imported-modules (source-module-closure
211 '((gnu build file-systems)
212 (gnu system uuid)))
213 #~(begin
214 (use-modules (gnu build file-systems)
215 (gnu system uuid))
216
217 (let ((uuid (uuid #$(uuid->string (file-system-device fs))
218 '#$(uuid-type (file-system-device fs)))))
219 (find-partition-by-uuid uuid)))))
220
221 (remote-let ((result remote-exp))
222 (unless result
223 (raise (formatted-message (G_ "no file system with UUID '~a'")
224 (uuid->string (file-system-device fs)))))))
225
226 (append (map check-literal-file-system
227 (filter (lambda (fs)
228 (string? (file-system-device fs)))
229 file-systems))
230 (map check-labeled-file-system
231 (filter (lambda (fs)
232 (file-system-label? (file-system-device fs)))
233 file-systems))
234 (map check-uuid-file-system
235 (filter (lambda (fs)
236 (uuid? (file-system-device fs)))
237 file-systems))))
238
239(define (machine-check-initrd-modules machine)
240 "Return a list of <remote-assertion> that raise a '&message' error condition
241if any of the modules needed by 'needed-for-boot' file systems in MACHINE are
242not available in the initrd."
243 (define file-systems
244 (filter file-system-needed-for-boot?
245 (operating-system-file-systems (machine-operating-system machine))))
246
247 (define (missing-modules fs)
248 (define remote-exp
249 (let ((device (file-system-device fs)))
250 (with-imported-modules (source-module-closure
251 '((gnu build file-systems)
252 (gnu build linux-modules)
253 (gnu system uuid)))
254 #~(begin
255 (use-modules (gnu build file-systems)
256 (gnu build linux-modules)
257 (gnu system uuid))
258
259 (define dev
260 #$(cond ((string? device) device)
261 ((uuid? device) #~(find-partition-by-uuid
262 (string->uuid
263 #$(uuid->string device))))
264 ((file-system-label? device)
265 #~(find-partition-by-label
266 #$(file-system-label->string device)))))
267
268 (missing-modules dev '#$(operating-system-initrd-modules
269 (machine-operating-system machine)))))))
270
271 (remote-let ((missing remote-exp))
272 (unless (null? missing)
273 (raise (condition
274 (&message
275 (message (format #f (G_ "missing modules for ~a:~{ ~a~}~%")
276 (file-system-device fs)
277 missing))))))))
278
279 (map missing-modules file-systems))
280
281(define* (machine-check-forward-update machine)
282 "Check whether we are making a forward update for MACHINE. Depending on its
283'allow-upgrades?' field, raise an error or display a warning if we are
284potentially downgrading it."
285 (define config
286 (machine-configuration machine))
287
288 (define validate-reconfigure
289 (if (machine-ssh-configuration-allow-downgrades? config)
290 warn-about-backward-reconfigure
291 ensure-forward-reconfigure))
292
293 (remote-let ((provenance #~(call-with-input-file
294 "/run/current-system/provenance"
295 read)))
296 (define channels
297 (sexp->system-provenance provenance))
298
299 (check-forward-update validate-reconfigure
300 #:current-channels channels)))
301
302(define (machine-check-building-for-appropriate-system machine)
303 "Raise a '&message' error condition if MACHINE is configured to be built
304locally and the 'system' field does not match the '%current-system' reported
305by MACHINE."
306 (let ((config (machine-configuration machine))
307 (system (remote-system (machine-ssh-session machine))))
308 (when (and (machine-ssh-configuration-build-locally? config)
309 (not (string= system (machine-ssh-configuration-system config))))
310 (raise (formatted-message (G_ "incorrect target system\
311 ('~a' was given, while the system reports that it is '~a')~%")
312 (machine-ssh-configuration-system config)
313 system)))))
314
315(define (check-deployment-sanity machine)
316 "Raise a '&message' error condition if it is clear that deploying MACHINE's
317'system' declaration would fail."
318 (define assertions
319 (append (machine-check-file-system-availability machine)
320 (machine-check-initrd-modules machine)
321 (list (machine-check-forward-update machine))))
322
323 (define aggregate-exp
324 ;; Gather all the expressions so that a single round-trip is enough to
325 ;; evaluate all the ASSERTIONS remotely.
326 #~(map (lambda (file)
327 (false-if-exception (primitive-load file)))
328 '#$(map (lambda (assertion)
329 (scheme-file "remote-assertion.scm"
330 (remote-assertion-expression assertion)))
331 assertions)))
332
333 ;; First check MACHINE's system type--an incorrect value for 'system' would
334 ;; cause subsequent invocations of 'remote-eval' to fail.
335 (machine-check-building-for-appropriate-system machine)
336
337 (mlet %store-monad ((values (machine-remote-eval machine aggregate-exp)))
338 (for-each (lambda (proc value)
339 (proc value))
340 (map remote-assertion-procedure assertions)
341 values)
342 (return #t)))
343
344
345;;;
346;;; System deployment.
347;;;
348
349(define (machine-boot-parameters machine)
350 "Monadic procedure returning a list of 'boot-parameters' for the generations
351of MACHINE's system profile, ordered from most recent to oldest."
352 (define bootable-kernel-arguments
353 (@@ (gnu system) bootable-kernel-arguments))
354
355 (define remote-exp
356 (with-extensions (list guile-gcrypt)
357 (with-imported-modules (source-module-closure
358 `(((guix config) => ,(make-config.scm))
359 (guix profiles)))
360 #~(begin
361 (use-modules (guix config)
362 (guix profiles)
363 (ice-9 textual-ports))
364
365 (define %system-profile
366 (string-append %state-directory "/profiles/system"))
367
368 (define (read-file path)
369 (call-with-input-file path
370 (lambda (port)
371 (get-string-all port))))
372
373 (map (lambda (generation)
374 (let* ((system-path (generation-file-name %system-profile
375 generation))
376 (boot-parameters-path (string-append system-path
377 "/parameters"))
378 (time (stat:mtime (lstat system-path))))
379 (list generation
380 system-path
381 time
382 (read-file boot-parameters-path))))
383 (reverse (generation-numbers %system-profile)))))))
384
385 (mlet* %store-monad ((generations (machine-remote-eval machine remote-exp)))
386 (return
387 (map (lambda (generation)
388 (match generation
389 ((generation system-path time serialized-params)
390 (let* ((params (call-with-input-string serialized-params
391 read-boot-parameters))
392 (root (boot-parameters-root-device params))
393 (label (boot-parameters-label params)))
394 (boot-parameters
395 (inherit params)
396 (label
397 (string-append label " (#"
398 (number->string generation) ", "
399 (let ((time (make-time time-utc 0 time)))
400 (date->string (time-utc->date time)
401 "~Y-~m-~d ~H:~M"))
402 ")"))
403 (kernel-arguments
404 (append (bootable-kernel-arguments system-path root)
405 (boot-parameters-kernel-arguments params))))))))
406 generations))))
407
408(define-syntax-rule (with-roll-back should-roll-back? mbody ...)
409 "Catch exceptions that arise when binding MBODY, a monadic expression in
410%STORE-MONAD, and collect their arguments in a &deploy-error condition, with
411the 'should-roll-back' field set to SHOULD-ROLL-BACK?"
412 (catch #t
413 (lambda ()
414 mbody ...)
415 (lambda args
416 (raise (condition (&deploy-error
417 (should-roll-back should-roll-back?)
418 (captured-args args)))))))
419
420(define (deploy-managed-host machine)
421 "Internal implementation of 'deploy-machine' for MACHINE instances with an
422environment type of 'managed-host."
423 (maybe-raise-unsupported-configuration-error machine)
424 (when (machine-ssh-configuration-authorize?
425 (machine-configuration machine))
426 (unless (file-exists? %public-key-file)
427 (raise (formatted-message (G_ "no signing key '~a'. \
428have you run 'guix archive --generate-key?'")
429 %public-key-file)))
430 (remote-authorize-signing-key (call-with-input-file %public-key-file
431 (lambda (port)
432 (string->canonical-sexp
433 (get-string-all port))))
434 (machine-ssh-session machine)
435 (machine-become-command machine)))
436 (mlet %store-monad ((_ (check-deployment-sanity machine))
437 (boot-parameters (machine-boot-parameters machine)))
438 (let* ((os (machine-operating-system machine))
439 (eval (cut machine-remote-eval machine <>))
440 (menu-entries (map boot-parameters->menu-entry boot-parameters))
441 (bootloader-configuration (operating-system-bootloader os))
442 (bootcfg (operating-system-bootcfg os menu-entries)))
443 (mbegin %store-monad
444 (with-roll-back #f
445 (switch-to-system eval os))
446 (with-roll-back #t
447 (mbegin %store-monad
448 (upgrade-shepherd-services eval os)
449 (install-bootloader eval bootloader-configuration bootcfg)))))))
450
451
452;;;
453;;; Roll-back.
454;;;
455
456(define (roll-back-managed-host machine)
457 "Internal implementation of 'roll-back-machine' for MACHINE instances with
458an environment type of 'managed-host."
459 (define remote-exp
460 (with-extensions (list guile-gcrypt)
461 (with-imported-modules (source-module-closure '((guix config)
462 (guix profiles)))
463 #~(begin
464 (use-modules (guix config)
465 (guix profiles))
466
467 (define %system-profile
468 (string-append %state-directory "/profiles/system"))
469
470 (define target-generation
471 (relative-generation %system-profile -1))
472
473 (if target-generation
474 (switch-to-generation %system-profile target-generation)
475 'error)))))
476
477 (define roll-back-failure
478 (condition (&message (message (G_ "could not roll-back machine")))))
479
480 (mlet* %store-monad ((boot-parameters (machine-boot-parameters machine))
481 (_ -> (if (< (length boot-parameters) 2)
482 (raise roll-back-failure)))
483 (entries -> (map boot-parameters->menu-entry
484 (list (second boot-parameters))))
485 (locale -> (boot-parameters-locale
486 (second boot-parameters)))
487 (store-dir -> (boot-parameters-store-directory-prefix
488 (second boot-parameters)))
489 (old-entries -> (map boot-parameters->menu-entry
490 (drop boot-parameters 2)))
491 (bootloader -> (operating-system-bootloader
492 (machine-operating-system machine)))
493 (bootcfg (lower-object
494 ((bootloader-configuration-file-generator
495 (bootloader-configuration-bootloader
496 bootloader))
497 bootloader entries
498 #:locale locale
499 #:store-directory-prefix store-dir
500 #:old-entries old-entries)))
501 (remote-result (machine-remote-eval machine remote-exp)))
502 (when (eqv? 'error remote-result)
503 (raise roll-back-failure))))
504
505
506;;;
507;;; Environment type.
508;;;
509
510(define managed-host-environment-type
511 (environment-type
512 (machine-remote-eval managed-host-remote-eval)
513 (deploy-machine deploy-managed-host)
514 (roll-back-machine roll-back-managed-host)
515 (name 'managed-host-environment-type)
516 (description "Provisioning for machines that are accessible over SSH
517and have a known host-name. This entails little more than maintaining an SSH
518connection to the host.")))
519
520(define (maybe-raise-unsupported-configuration-error machine)
521 "Raise an error if MACHINE's configuration is not an instance of
522<machine-ssh-configuration>."
523 (let ((config (machine-configuration machine))
524 (environment (environment-type-name (machine-environment machine))))
525 (unless (and config (machine-ssh-configuration? config))
526 (raise (formatted-message (G_ "unsupported machine configuration '~a'
527for environment of type '~a'")
528 config
529 environment)))))
530
531;; Local Variables:
532;; eval: (put 'remote-let 'scheme-indent-function 1)
533;; End: