| 1 | /* |
| 2 | * setup.ld |
| 3 | * |
| 4 | * Linker script for the i386 setup code |
| 5 | */ |
| 6 | OUTPUT_FORMAT("elf32-i386") |
| 7 | OUTPUT_ARCH(i386) |
| 8 | ENTRY(_start) |
| 9 | |
| 10 | SECTIONS |
| 11 | { |
| 12 | . = 0; |
| 13 | .bstext : { |
| 14 | *(.bstext) |
| 15 | . = 495; |
| 16 | } =0xffffffff |
| 17 | |
| 18 | .header : { *(.header) } |
| 19 | .entrytext : { *(.entrytext) } |
| 20 | .inittext : { *(.inittext) } |
| 21 | .initdata : { *(.initdata) } |
| 22 | __end_init = .; |
| 23 | |
| 24 | .text : { *(.text .text.*) } |
| 25 | .text32 : { *(.text32) } |
| 26 | |
| 27 | .pecompat : { *(.pecompat) } |
| 28 | PROVIDE(pecompat_fsize = setup_size - pecompat_fstart); |
| 29 | |
| 30 | . = ALIGN(16); |
| 31 | .rodata : { *(.rodata*) } |
| 32 | |
| 33 | .videocards : { |
| 34 | video_cards = .; |
| 35 | *(.videocards) |
| 36 | video_cards_end = .; |
| 37 | } |
| 38 | |
| 39 | . = ALIGN(16); |
| 40 | .data : { *(.data*) } |
| 41 | |
| 42 | .signature : { |
| 43 | setup_sig = .; |
| 44 | LONG(0x5a5aaa55) |
| 45 | |
| 46 | setup_size = ALIGN(ABSOLUTE(.), 4096); |
| 47 | setup_sects = ABSOLUTE(setup_size / 512); |
| 48 | ASSERT(setup_sects >= 5, "The setup must be at least 5 sectors in size"); |
| 49 | ASSERT(setup_sects <= 64, "The setup must be at most 64 sectors in size"); |
| 50 | } |
| 51 | |
| 52 | . = ALIGN(16); |
| 53 | .bss : |
| 54 | { |
| 55 | __bss_start = .; |
| 56 | *(.bss) |
| 57 | __bss_end = .; |
| 58 | } |
| 59 | . = ALIGN(16); |
| 60 | _end = .; |
| 61 | |
| 62 | /DISCARD/ : { |
| 63 | *(.note*) |
| 64 | } |
| 65 | |
| 66 | /* |
| 67 | * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility: |
| 68 | */ |
| 69 | . = ASSERT(_end <= 0x8000, "Setup too big!"); |
| 70 | . = ASSERT(hdr == 0x1f1, "The setup header has the wrong offset!"); |
| 71 | /* Necessary for the very-old-loader check to work... */ |
| 72 | . = ASSERT(__end_init <= 5*512, "init sections too big!"); |
| 73 | |
| 74 | } |