projects/linux·blob master · refs

716 lines · 16.8 KiB

1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3#
4# Copyright 2005-2009 - Steven Rostedt
5#
6# It's simple enough to figure out how this works.
7# If not, then you can ask me at [email protected]
8#
9# What it does?
10#
11# If you have installed a Linux kernel from a distribution
12# that turns on way too many modules than you need, and
13# you only want the modules you use, then this program
14# is perfect for you.
15#
16# It gives you the ability to turn off all the modules that are
17# not loaded on your system.
18#
19# Howto:
20#
21# 1. Boot up the kernel that you want to stream line the config on.
22# 2. Change directory to the directory holding the source of the
23# kernel that you just booted.
24# 3. Copy the configuration file to this directory as .config
25# 4. Have all your devices that you need modules for connected and
26# operational (make sure that their corresponding modules are loaded)
27# 5. Run this script redirecting the output to some other file
28# like config_strip.
29# 6. Back up your old config (if you want too).
30# 7. copy the config_strip file to .config
31# 8. Run "make oldconfig"
32#
33# Now your kernel is ready to be built with only the modules that
34# are loaded.
35#
36# Here's what I did with my Debian distribution.
37#
38# cd /usr/src/linux-2.6.10
39# cp /boot/config-2.6.10-1-686-smp .config
40# ~/bin/streamline_config > config_strip
41# mv .config config_sav
42# mv config_strip .config
43# make oldconfig
44#
45use warnings;
46use strict;
47use Getopt::Long;
48
49# set the environment variable LOCALMODCONFIG_DEBUG to get
50# debug output.
51my $debugprint = 0;
52$debugprint = 1 if (defined($ENV{LOCALMODCONFIG_DEBUG}));
53
54sub dprint {
55 return if (!$debugprint);
56 print STDERR @_;
57}
58
59my $uname = `uname -r`;
60chomp $uname;
61
62my @searchconfigs = (
63 {
64 "file" => ".config",
65 "exec" => "cat",
66 },
67 {
68 "file" => "/proc/config.gz",
69 "exec" => "zcat",
70 },
71 {
72 "file" => "/boot/config-$uname",
73 "exec" => "cat",
74 },
75 {
76 "file" => "/boot/vmlinuz-$uname",
77 "exec" => "scripts/extract-ikconfig",
78 "test" => "scripts/extract-ikconfig",
79 },
80 {
81 "file" => "vmlinux",
82 "exec" => "scripts/extract-ikconfig",
83 "test" => "scripts/extract-ikconfig",
84 },
85 {
86 "file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
87 "exec" => "scripts/extract-ikconfig",
88 "test" => "scripts/extract-ikconfig",
89 },
90 {
91 "file" => "kernel/configs.ko",
92 "exec" => "scripts/extract-ikconfig",
93 "test" => "scripts/extract-ikconfig",
94 },
95 {
96 "file" => "kernel/configs.o",
97 "exec" => "scripts/extract-ikconfig",
98 "test" => "scripts/extract-ikconfig",
99 },
100);
101
102sub read_config {
103 foreach my $conf (@searchconfigs) {
104 my $file = $conf->{"file"};
105
106 next if ( ! -f "$file");
107
108 if (defined($conf->{"test"})) {
109 `$conf->{"test"} $conf->{"file"} 2>/dev/null`;
110 next if ($?);
111 }
112
113 my $exec = $conf->{"exec"};
114
115 print STDERR "using config: '$file'\n";
116
117 open(my $infile, '-|', "$exec $file") || die "Failed to run $exec $file";
118 my @x = <$infile>;
119 close $infile;
120 return @x;
121 }
122 die "No config file found";
123}
124
125my @config_file = read_config;
126
127# Parse options
128my $localmodconfig = 0;
129my $localyesconfig = 0;
130
131GetOptions("localmodconfig" => \$localmodconfig,
132 "localyesconfig" => \$localyesconfig);
133
134# Get the build source and top level Kconfig file (passed in)
135my $ksource = ($ARGV[0] ? $ARGV[0] : '.');
136my $kconfig = $ARGV[1];
137my $lsmod_file = $ENV{'LSMOD'};
138
139my @makefiles = `find $ksource -name Makefile -or -name Kbuild 2>/dev/null`;
140chomp @makefiles;
141
142my %depends;
143my %selects;
144my %prompts;
145my %objects;
146my %config2kfile;
147my %defaults;
148my $var;
149my $iflevel = 0;
150my @ifdeps;
151
152# prevent recursion
153my %read_kconfigs;
154
155sub read_kconfig {
156 my ($kconfig) = @_;
157
158 my $state = "NONE";
159 my $config;
160
161 my $cont = 0;
162 my $line;
163
164 my $source = "$ksource/$kconfig";
165 my $last_source = "";
166
167 # Check for any environment variables used
168 while ($source =~ /\$\((\w+)\)/ && $last_source ne $source) {
169 my $env = $1;
170 $last_source = $source;
171 $source =~ s/\$\($env\)/$ENV{$env}/;
172 }
173
174 open(my $kinfile, '<', $source) || die "Can't open $source";
175 while (<$kinfile>) {
176 chomp;
177
178 # Make sure that lines ending with \ continue
179 if ($cont) {
180 $_ = $line . " " . $_;
181 }
182
183 if (s/\\$//) {
184 $cont = 1;
185 $line = $_;
186 next;
187 }
188
189 $cont = 0;
190
191 # collect any Kconfig sources
192 if (/^source\s+"?([^"]+)/) {
193 my $kconfig = $1;
194 # prevent reading twice.
195 if (!defined($read_kconfigs{$kconfig})) {
196 $read_kconfigs{$kconfig} = 1;
197 read_kconfig($kconfig);
198 }
199 next;
200 }
201
202 # configs found
203 if (/^\s*(menu)?config\s+(\S+)\s*$/) {
204 $state = "NEW";
205 $config = $2;
206 $config2kfile{"CONFIG_$config"} = $kconfig;
207
208 # Add depends for 'if' nesting
209 for (my $i = 0; $i < $iflevel; $i++) {
210 if ($i) {
211 $depends{$config} .= " " . $ifdeps[$i];
212 } else {
213 $depends{$config} = $ifdeps[$i];
214 }
215 $state = "DEP";
216 }
217
218 # collect the depends for the config
219 } elsif ($state eq "NEW" && /^\s*depends\s+on\s+(.*)$/) {
220 $state = "DEP";
221 $depends{$config} = $1;
222 } elsif ($state eq "DEP" && /^\s*depends\s+on\s+(.*)$/) {
223 $depends{$config} .= " " . $1;
224 } elsif ($state ne "NONE" && /^\s*def(_(bool|tristate)|ault)\s+(\S.*)$/) {
225 my $dep = $3;
226 $defaults{$config} = 1;
227 if ($dep !~ /^\s*(y|m|n)\s*$/) {
228 $dep =~ s/.*\sif\s+//;
229 $depends{$config} .= " " . $dep;
230 dprint "Added default depends $dep to $config\n";
231 }
232
233 # Get the configs that select this config
234 } elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
235 my $conf = $1;
236 if (defined($selects{$conf})) {
237 $selects{$conf} .= " " . $config;
238 } else {
239 $selects{$conf} = $config;
240 }
241
242 # configs without prompts must be selected
243 } elsif ($state ne "NONE" && /^\s*(tristate\s+\S|prompt\b)/) {
244 # note if the config has a prompt
245 $prompts{$config} = 1;
246
247 # Check for if statements
248 } elsif (/^if\s+(.*\S)\s*$/) {
249 my $deps = $1;
250 # remove beginning and ending non text
251 $deps =~ s/^[^a-zA-Z0-9_]*//;
252 $deps =~ s/[^a-zA-Z0-9_]*$//;
253
254 my @deps = split /[^a-zA-Z0-9_]+/, $deps;
255
256 $ifdeps[$iflevel++] = join ':', @deps;
257
258 } elsif (/^endif/) {
259
260 $iflevel-- if ($iflevel);
261
262 # stop on "help" and keywords that end a menu entry
263 } elsif (/^\s*(---)?help(---)?\s*$/ || /^(comment|choice|menu)\b/) {
264 $state = "NONE";
265 }
266 }
267 close($kinfile);
268}
269
270if ($kconfig) {
271 read_kconfig($kconfig);
272}
273
274# Makefiles can use variables to define their dependencies
275sub convert_vars {
276 my ($line, %vars) = @_;
277
278 my $process = "";
279
280 while ($line =~ s/^(.*?)(\$\((.*?)\))//) {
281 my $start = $1;
282 my $variable = $2;
283 my $var = $3;
284
285 if (defined($vars{$var})) {
286 $process .= $start . $vars{$var};
287 } else {
288 $process .= $start . $variable;
289 }
290 }
291
292 $process .= $line;
293
294 return $process;
295}
296
297# Read all Makefiles to map the configs to the objects
298foreach my $makefile (@makefiles) {
299
300 my $line = "";
301 my %make_vars;
302
303 open(my $infile, '<', $makefile) || die "Can't open $makefile";
304 while (<$infile>) {
305 # if this line ends with a backslash, continue
306 chomp;
307 if (/^(.*)\\$/) {
308 $line .= $1;
309 next;
310 }
311
312 $line .= $_;
313 $_ = $line;
314 $line = "";
315
316 my $objs;
317
318 # Convert variables in a line (could define configs)
319 $_ = convert_vars($_, %make_vars);
320
321 # collect objects after obj-$(CONFIG_FOO_BAR)
322 if (/obj-\$[({](CONFIG_[^})]*)[)}]\s*[+:]?=\s*(.*)/) {
323 $var = $1;
324 $objs = $2;
325
326 # check if variables are set
327 } elsif (/^\s*(\S+)\s*[:]?=\s*(.*\S)/) {
328 $make_vars{$1} = $2;
329 }
330 if (defined($objs)) {
331 foreach my $obj (split /\s+/,$objs) {
332 $obj =~ s/-/_/g;
333 if ($obj =~ /(.*)\.o$/) {
334 # Objects may be enabled by more than one config.
335 # Store configs in an array.
336 my @arr;
337
338 if (defined($objects{$1})) {
339 @arr = @{$objects{$1}};
340 }
341
342 $arr[$#arr+1] = $var;
343
344 # The objects have a hash mapping to a reference
345 # of an array of configs.
346 $objects{$1} = \@arr;
347 }
348 }
349 }
350 }
351 close($infile);
352}
353
354my %modules;
355my $linfile;
356
357if (defined($lsmod_file)) {
358 if ( ! -f $lsmod_file) {
359 if ( -f $ENV{'objtree'}."/".$lsmod_file) {
360 $lsmod_file = $ENV{'objtree'}."/".$lsmod_file;
361 } else {
362 die "$lsmod_file not found";
363 }
364 }
365
366 my $otype = ( -x $lsmod_file) ? '-|' : '<';
367 open($linfile, $otype, $lsmod_file);
368
369} else {
370
371 # see what modules are loaded on this system
372 my $lsmod;
373
374 foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
375 if ( -x "$dir/lsmod" ) {
376 $lsmod = "$dir/lsmod";
377 last;
378 }
379 }
380 if (!defined($lsmod)) {
381 # try just the path
382 $lsmod = "lsmod";
383 }
384
385 open($linfile, '-|', $lsmod) || die "Can not call lsmod with $lsmod";
386}
387
388while (<$linfile>) {
389 next if (/^Module/); # Skip the first line.
390 if (/^(\S+)/) {
391 $modules{$1} = 1;
392 }
393}
394close ($linfile);
395
396# add to the configs hash all configs that are needed to enable
397# a loaded module. This is a direct obj-${CONFIG_FOO} += bar.o
398# where we know we need bar.o so we add FOO to the list.
399my %configs;
400foreach my $module (keys(%modules)) {
401 if (defined($objects{$module})) {
402 my @arr = @{$objects{$module}};
403 foreach my $conf (@arr) {
404 $configs{$conf} = $module;
405 dprint "$conf added by direct ($module)\n";
406 if ($debugprint) {
407 my $c=$conf;
408 $c =~ s/^CONFIG_//;
409 if (defined($depends{$c})) {
410 dprint " deps = $depends{$c}\n";
411 } else {
412 dprint " no deps\n";
413 }
414 }
415 }
416 } else {
417 # Most likely, someone has a custom (binary?) module loaded.
418 print STDERR "$module config not found!\n";
419 }
420}
421
422# Read the current config, and see what is enabled. We want to
423# ignore configs that we would not enable anyway.
424
425my %orig_configs;
426my $valid = "A-Za-z_0-9";
427
428foreach my $line (@config_file) {
429 $_ = $line;
430
431 if (/(CONFIG_[$valid]*)=(m|y)/) {
432 $orig_configs{$1} = $2;
433 }
434}
435
436my $repeat = 1;
437
438my $depconfig;
439
440#
441# Note, we do not care about operands (like: &&, ||, !) we want to add any
442# config that is in the depend list of another config. This script does
443# not enable configs that are not already enabled. If we come across a
444# config A that depends on !B, we can still add B to the list of depends
445# to keep on. If A was on in the original config, B would not have been
446# and B would not be turned on by this script.
447#
448sub parse_config_depends
449{
450 my ($p) = @_;
451
452 while ($p =~ /[$valid]/) {
453
454 if ($p =~ /^[^$valid]*([$valid]+)/) {
455 my $conf = "CONFIG_" . $1;
456
457 $p =~ s/^[^$valid]*[$valid]+//;
458
459 # We only need to process if the depend config is a module
460 if (!defined($orig_configs{$conf}) || $orig_configs{$conf} eq "y") {
461 next;
462 }
463
464 if (!defined($configs{$conf})) {
465 # We must make sure that this config has its
466 # dependencies met.
467 $repeat = 1; # do again
468 dprint "$conf selected by depend $depconfig\n";
469 $configs{$conf} = 1;
470 }
471 } else {
472 die "this should never happen";
473 }
474 }
475}
476
477# Select is treated a bit differently than depends. We call this
478# when a config has no prompt and requires another config to be
479# selected. We use to just select all configs that selected this
480# config, but found that that can balloon into enabling hundreds
481# of configs that we do not care about.
482#
483# The idea is we look at all the configs that select it. If one
484# is already in our list of configs to enable, then there's nothing
485# else to do. If there isn't, we pick the first config that was
486# enabled in the original config and use that.
487sub parse_config_selects
488{
489 my ($config, $p) = @_;
490
491 my $next_config;
492
493 while ($p =~ /[$valid]/) {
494
495 if ($p =~ /^[^$valid]*([$valid]+)/) {
496 my $conf = "CONFIG_" . $1;
497
498 $p =~ s/^[^$valid]*[$valid]+//;
499
500 # Make sure that this config exists in the current .config file
501 if (!defined($orig_configs{$conf})) {
502 dprint "$conf not set for $config select\n";
503 next;
504 }
505
506 # Check if something other than a module selects this config
507 if (defined($orig_configs{$conf}) && $orig_configs{$conf} ne "m") {
508 dprint "$conf (non module) selects $config, we are good\n";
509 # we are good with this
510 return;
511 }
512 if (defined($configs{$conf})) {
513 dprint "$conf selects $config so we are good\n";
514 # A set config selects this config, we are good
515 return;
516 }
517 # Set this config to be selected
518 if (!defined($next_config)) {
519 $next_config = $conf;
520 }
521 } else {
522 die "this should never happen";
523 }
524 }
525
526 # If no possible config selected this, then something happened.
527 if (!defined($next_config)) {
528
529 # Some config options have no prompt, and nothing selects them, but
530 # they stay turned on once the final checks for the configs
531 # are done. These configs have a default option, so turn off the
532 # warnings for configs with default options.
533 if (!defined($defaults{$config})) {
534 print STDERR "WARNING: $config is required, but nothing in the\n";
535 print STDERR " current config selects it.\n";
536 }
537
538 return;
539 }
540
541 # If we are here, then we found no config that is set and
542 # selects this config. Repeat.
543 $repeat = 1;
544 # Make this config need to be selected
545 $configs{$next_config} = 1;
546 dprint "$next_config selected by select $config\n";
547}
548
549my %process_selects;
550
551# loop through all configs, select their dependencies.
552sub loop_depend {
553 $repeat = 1;
554
555 while ($repeat) {
556 $repeat = 0;
557
558 forloop:
559 foreach my $config (keys %configs) {
560
561 # If this config is not a module, we do not need to process it
562 if (defined($orig_configs{$config}) && $orig_configs{$config} ne "m") {
563 next forloop;
564 }
565
566 $config =~ s/^CONFIG_//;
567 $depconfig = $config;
568
569 if (defined($depends{$config})) {
570 # This config has dependencies. Make sure they are also included
571 parse_config_depends $depends{$config};
572 }
573
574 # If the config has no prompt, then we need to check if a config
575 # that is enabled selected it. Or if we need to enable one.
576 if (!defined($prompts{$config}) && defined($selects{$config})) {
577 $process_selects{$config} = 1;
578 }
579 }
580 }
581}
582
583sub loop_select {
584
585 foreach my $config (keys %process_selects) {
586 $config =~ s/^CONFIG_//;
587
588 dprint "Process select $config\n";
589
590 # config has no prompt and must be selected.
591 parse_config_selects $config, $selects{$config};
592 }
593}
594
595while ($repeat) {
596 # Get the first set of configs and their dependencies.
597 loop_depend;
598
599 $repeat = 0;
600
601 # Now we need to see if we have to check selects;
602 loop_select;
603}
604
605my %setconfigs;
606my @preserved_kconfigs;
607if (defined($ENV{'LMC_KEEP'})) {
608 @preserved_kconfigs = split(/:/,$ENV{LMC_KEEP});
609}
610
611sub in_preserved_kconfigs {
612 my $kconfig = $config2kfile{$_[0]};
613 if (!defined($kconfig)) {
614 return 0;
615 }
616 foreach my $excl (@preserved_kconfigs) {
617 if($kconfig =~ /^$excl/) {
618 return 1;
619 }
620 }
621 return 0;
622}
623
624# Finally, read the .config file and turn off any module enabled that
625# we could not find a reason to keep enabled.
626foreach my $line (@config_file) {
627 $_ = $line;
628
629 if (/CONFIG_IKCONFIG/) {
630 if (/# CONFIG_IKCONFIG is not set/) {
631 # enable IKCONFIG at least as a module
632 print "CONFIG_IKCONFIG=m\n";
633 # don't ask about PROC
634 print "# CONFIG_IKCONFIG_PROC is not set\n";
635 } else {
636 print;
637 }
638 next;
639 }
640
641 if (/CONFIG_MODULE_SIG_KEY="(.+)"/) {
642 my $orig_cert = $1;
643 my $default_cert = "certs/signing_key.pem";
644
645 # Check that the logic in this script still matches the one in Kconfig
646 if (!defined($depends{"MODULE_SIG_KEY"}) ||
647 $depends{"MODULE_SIG_KEY"} !~ /"\Q$default_cert\E"/) {
648 print STDERR "WARNING: MODULE_SIG_KEY assertion failure, ",
649 "update needed to ", __FILE__, " line ", __LINE__, "\n";
650 print;
651 } elsif ($orig_cert ne $default_cert && ! -f $orig_cert) {
652 print STDERR "Module signature verification enabled but ",
653 "module signing key \"$orig_cert\" not found. Resetting ",
654 "signing key to default value.\n";
655 print "CONFIG_MODULE_SIG_KEY=\"$default_cert\"\n";
656 } else {
657 print;
658 }
659 next;
660 }
661
662 if (/CONFIG_SYSTEM_TRUSTED_KEYS="(.+)"/) {
663 my $orig_keys = $1;
664
665 if (! -f $orig_keys) {
666 print STDERR "System keyring enabled but keys \"$orig_keys\" ",
667 "not found. Resetting keys to default value.\n";
668 print "CONFIG_SYSTEM_TRUSTED_KEYS=\"\"\n";
669 } else {
670 print;
671 }
672 next;
673 }
674
675 if (/^(CONFIG.*)=(m|y)/) {
676 if (in_preserved_kconfigs($1)) {
677 dprint "Preserve config $1";
678 print;
679 next;
680 }
681 if (defined($configs{$1})) {
682 if ($localyesconfig) {
683 $setconfigs{$1} = 'y';
684 print "$1=y\n";
685 next;
686 } else {
687 $setconfigs{$1} = $2;
688 }
689 } elsif ($2 eq "m") {
690 print "# $1 is not set\n";
691 next;
692 }
693 }
694 print;
695}
696
697# Integrity check, make sure all modules that we want enabled do
698# indeed have their configs set.
699loop:
700foreach my $module (keys(%modules)) {
701 if (defined($objects{$module})) {
702 my @arr = @{$objects{$module}};
703 foreach my $conf (@arr) {
704 if (defined($setconfigs{$conf})) {
705 next loop;
706 }
707 }
708 print STDERR "module $module did not have configs";
709 foreach my $conf (@arr) {
710 print STDERR " " , $conf;
711 }
712 print STDERR "\n";
713 }
714}
715
716# vim: softtabstop=4