projects/guix·blob javascript-team · refs

184 lines · 6.6 KiB

1;;; GNU Guix --- Functional package management for GNU
2;;; Copyright © 2018 Alex Vong <[email protected]>
3;;; Copyright © 2020, 2021 Ludovic Courtès <[email protected]>
4;;;
5;;; This file is part of GNU Guix.
6;;;
7;;; GNU Guix is free software; you can redistribute it and/or modify it
8;;; under the terms of the GNU General Public License as published by
9;;; the Free Software Foundation; either version 3 of the License, or (at
10;;; your option) any later version.
11;;;
12;;; GNU Guix is distributed in the hope that it will be useful, but
13;;; WITHOUT ANY WARRANTY; without even the implied warranty of
14;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15;;; GNU General Public License for more details.
16;;;
17;;; You should have received a copy of the GNU General Public License
18;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
19
20(define-module (guix build-system clojure)
21 #:use-module (guix build clojure-utils)
22 #:use-module (guix build-system)
23 #:use-module (guix build-system ant)
24 #:use-module ((guix build-system gnu)
25 #:select (standard-packages)
26 #:prefix gnu:)
27
28 #:use-module (guix gexp)
29 #:use-module (guix store)
30 #:use-module (guix monads)
31 #:use-module (guix packages)
32 #:use-module ((guix search-paths)
33 #:select
34 ((search-path-specification->sexp . search-path-spec->sexp)))
35 #:use-module (guix utils)
36 #:export (%clojure-build-system-modules
37 clojure-build
38 clojure-build-system))
39
40;; Commentary:
41;;
42;; Standard build procedure for Clojure packages.
43;;
44;; Code:
45
46(define-with-docs %clojure-build-system-modules
47 "Build-side modules imported by default."
48 `((guix build clojure-build-system)
49 (guix build clojure-utils)
50 (guix build guile-build-system)
51 ,@%ant-build-system-modules))
52
53(define %default-modules
54 ;; Modules in scope in the build-side environment.
55 '((guix build clojure-build-system)
56 (guix build clojure-utils)
57 (guix build utils)))
58
59(define (default-clojure)
60 "The default Clojure package."
61 (@* (gnu packages clojure) clojure))
62
63(define (default-jdk)
64 "The default JDK package."
65 (@* (gnu packages java) icedtea))
66
67(define (default-zip)
68 "The default ZIP package."
69 (@* (gnu packages compression) zip))
70
71(define* (lower name
72 #:key
73 source target
74 inputs native-inputs
75 (clojure (default-clojure))
76 (jdk (default-jdk))
77 (zip (default-zip))
78 outputs system
79 #:allow-other-keys
80 #:rest arguments)
81 "Return a bag for NAME."
82 (let ((private-keywords '(#:target #:inputs #:native-inputs
83 #:clojure #:jdk #:zip)))
84
85 (if target
86 #f ; FIXME: No cross-compilation for
87 ; clojure-build-system yet
88 (bag (name name)
89 (system system)
90 (host-inputs `(,@(if source
91 `(("source" ,source))
92 '())
93 ,@inputs
94 ,@(gnu:standard-packages)))
95 (build-inputs `(("clojure" ,clojure)
96 ("jdk" ,jdk "jdk")
97 ("zip" ,zip)
98 ,@native-inputs))
99 (outputs outputs)
100 (build clojure-build)
101 (arguments (strip-keyword-arguments private-keywords
102 arguments))))))
103
104(define* (clojure-build name inputs
105 #:key
106 source
107 (source-dirs `',%source-dirs)
108 (java-source-dirs `',%java-source-dirs)
109 (test-dirs `',%test-dirs)
110 (compile-dir %compile-dir)
111 (java-compile-dir %java-compile-dir)
112
113 (jar-names `',(package-name->jar-names name))
114 (main-class %main-class)
115 (omit-source? %omit-source?)
116
117 (aot-include `',%aot-include)
118 (aot-exclude `',%aot-exclude)
119
120 doc-dirs ; no sensible default
121 (doc-regex %doc-regex)
122
123 (tests? %tests?)
124 (test-include `',%test-include)
125 (test-exclude `',%test-exclude)
126
127 (phases '%standard-phases)
128 (outputs '("out"))
129 (search-paths '())
130 (system (%current-system))
131 (guile #f)
132
133 (imported-modules %clojure-build-system-modules)
134 (modules %default-modules))
135 "Build SOURCE with INPUTS."
136 (define builder
137 (with-imported-modules imported-modules
138 #~(begin
139 (use-modules #$@(sexp->gexp modules))
140
141 (clojure-build #:name #$name
142 #:source #+source
143
144 #:source-dirs #$source-dirs
145 #:java-source-dirs #$java-source-dirs
146 #:test-dirs #$test-dirs
147 #:compile-dir #$compile-dir
148 #:java-compile-dir #$java-compile-dir
149
150 #:jar-names #$jar-names
151 #:main-class #$main-class
152 #:omit-source? #$omit-source?
153
154 #:aot-include #$aot-include
155 #:aot-exclude #$aot-exclude
156
157 #:doc-dirs #$doc-dirs
158 #:doc-regex #$doc-regex
159
160 #:tests? #$tests?
161 #:test-include #$test-include
162 #:test-exclude #$test-exclude
163
164 #:phases #$phases
165 #:outputs #$(outputs->gexp outputs)
166 #:search-paths '#$(sexp->gexp
167 (map search-path-spec->sexp
168 search-paths))
169 #:system #$system
170 #:inputs #$(input-tuples->gexp inputs)))))
171
172 (mlet %store-monad ((guile (package->derivation (or guile (default-guile))
173 system #:graft? #f)))
174 (gexp->derivation name builder
175 #:system system
176 #:guile-for-build guile)))
177
178(define clojure-build-system
179 (build-system
180 (name 'clojure)
181 (description "Simple Clojure build system using plain old 'compile'")
182 (lower lower)))
183
184;;; clojure.scm ends here