projects/linux·blob master · refs

72 lines · 1.6 KiB

1/* SPDX-License-Identifier: GPL-2.0 */
2/* Copyright (C) 2023 Rivos Inc. */
3
4#include <linux/cfi_types.h>
5#include <linux/linkage.h>
6#include <asm/asm.h>
7
8 .text
9
10/* void __riscv_copy_words_unaligned(void *, const void *, size_t) */
11/* Performs a memcpy without aligning buffers, using word loads and stores. */
12/* Note: The size is truncated to a multiple of 8 * SZREG */
13SYM_TYPED_FUNC_START(__riscv_copy_words_unaligned)
14 andi a4, a2, ~((8*SZREG)-1)
15 beqz a4, 2f
16 add a3, a1, a4
171:
18 REG_L a4, 0(a1)
19 REG_L a5, SZREG(a1)
20 REG_L a6, 2*SZREG(a1)
21 REG_L a7, 3*SZREG(a1)
22 REG_L t0, 4*SZREG(a1)
23 REG_L t1, 5*SZREG(a1)
24 REG_L t2, 6*SZREG(a1)
25 REG_L t3, 7*SZREG(a1)
26 REG_S a4, 0(a0)
27 REG_S a5, SZREG(a0)
28 REG_S a6, 2*SZREG(a0)
29 REG_S a7, 3*SZREG(a0)
30 REG_S t0, 4*SZREG(a0)
31 REG_S t1, 5*SZREG(a0)
32 REG_S t2, 6*SZREG(a0)
33 REG_S t3, 7*SZREG(a0)
34 addi a0, a0, 8*SZREG
35 addi a1, a1, 8*SZREG
36 bltu a1, a3, 1b
37
382:
39 ret
40SYM_FUNC_END(__riscv_copy_words_unaligned)
41
42/* void __riscv_copy_bytes_unaligned(void *, const void *, size_t) */
43/* Performs a memcpy without aligning buffers, using only byte accesses. */
44/* Note: The size is truncated to a multiple of 8 */
45SYM_TYPED_FUNC_START(__riscv_copy_bytes_unaligned)
46 andi a4, a2, ~(8-1)
47 beqz a4, 2f
48 add a3, a1, a4
491:
50 lb a4, 0(a1)
51 lb a5, 1(a1)
52 lb a6, 2(a1)
53 lb a7, 3(a1)
54 lb t0, 4(a1)
55 lb t1, 5(a1)
56 lb t2, 6(a1)
57 lb t3, 7(a1)
58 sb a4, 0(a0)
59 sb a5, 1(a0)
60 sb a6, 2(a0)
61 sb a7, 3(a0)
62 sb t0, 4(a0)
63 sb t1, 5(a0)
64 sb t2, 6(a0)
65 sb t3, 7(a0)
66 addi a0, a0, 8
67 addi a1, a1, 8
68 bltu a1, a3, 1b
69
702:
71 ret
72SYM_FUNC_END(__riscv_copy_bytes_unaligned)